function @SentenceCase(&Param: string): string
  %---------------------------------------------------------
  % Function that changes the cases of the characters in   -
  % a string to output the string like a sentence (first   -
  % letter of every sentence in uppercase).                -
  %---------------------------------------------------------
  % Input:  &Param       String to convert.                -
  % Output: Converted string looking like a sentence.      -
  % Uses:   None.                                          -
  %---------------------------------------------------------
  % Written by:   Marty Jacques, Objectif Lune             -
  % Last updated: November 10, 2004                        -
  % Modified by Raphaël to handle directionals.            -
  %---------------------------------------------------------
  define(&i,integer,0)
  define(&p,integer,0)
  define(&bStartSentence,boolean,true)
  define(&Work,string,'')
  define(&Upper,string,'ABCDEFGHIJKLMNOPQRSTUVWXYZÀÂÄÉÈÊËÌÎÏÒÔÖÙÛÜÇ')
  define(&Lower,string,'abcdefghijklmnopqrstuvwxyzàâäéèêëìîïòôöùûüç')
  for(&i,1,1,length(&Param))
    if(pos(mid(&Param,&i,1),'.;:!?')>0)
      &bStartSentence:=true
    endif
    if(&bStartSentence)
      %Need uppercase
      &p:=pos(mid(&Param,&i,1),&Lower)

      % Handle directionals.
      if(pos(mid(&Param,&i,2), 'NW|SW|NE|SE') > 0)
        set(&Work,&Work + mid(&Param,&i,2))
        &i := &i + 1
      elseif()
        if(&p>0)
          set(&Work,&Work + mid(&Upper,&p,1))
        elseif()
          set(&Work,&Work + mid(&Param,&i,1))
        endif()
      endif()

      if(&bStartSentence and (pos(mid(&Param,&i,1),'.;:!?_ ')=0))
        &bStartSentence:=false
      endif
    elseif()
      %Need lowercase
      &p:=pos(mid(&Param,&i,1),&Upper)

      % Handle directionals.
      if(pos(mid(&Param,&i,2), 'NW|SW|NE|SE') > 0)
        set(&Work,&Work + mid(&Param,&i,2))
        &i := &i + 1
      elseif()
        if(&p>0)
          set(&Work,&Work + mid(&Lower,&p,1))
        elseif()
          set(&Work,&Work + mid(&Param,&i,1))
        endif()
      endif()

    endif()
  endfor()
  &Result:=&Work
endfunction()

=uppercase(@(1,1,50))